Transport Tycoon Forums

Code: Select all

			Debug("Cargo wants to go to town...");
			local townTiles = AITileList();
			local min = MIN_DISTANCE;
			local max = MAX_DISTANCE;
			SafeAddRectangle(townTiles, place1, max, min);
			Debug("Made a list of this many tiles: " + townTiles.Count() + ", min: " + min + ", Max: " + max);
			while (townTiles.Count() > 150000) { // TODO Guessed value to prevent CPU excessive usage error
				min++;
				max--;
				townTiles = AITileList();
				SafeAddRectangle(townTiles, place1, max, min);
				Debug("Adapted list to this many tiles: " + townTiles.Count() + ", min: " + min + ", Max: " + max);
			}

Code: Select all

/**
 * Add a rectangular area to an AITileList containing tiles that are within /radius/
 * tiles from the center tile, taking the edges of the map into account.
 */  
function SafeAddRectangle(list, tile, radius, exclude_radius = 0) {
	if (tile == null) {
		Error("Got a nullpointer");
		return;
	}

	local x1 = max(1, AIMap.GetTileX(tile) - radius);
	local y1 = max(1, AIMap.GetTileY(tile) - radius);
	
	local x2 = min(AIMap.GetMapSizeX() - 2, AIMap.GetTileX(tile) + radius);
	local y2 = min(AIMap.GetMapSizeY() - 2, AIMap.GetTileY(tile) + radius);
	
	list.AddRectangle(AIMap.GetTileIndex(x1, y1),AIMap.GetTileIndex(x2, y2));

	if (exclude_radius > 0) {
		x1 = max(1, AIMap.GetTileX(tile) - exclude_radius);
		y1 = max(1, AIMap.GetTileY(tile) - exclude_radius);

		x2 = min(AIMap.GetMapSizeX() - 2, AIMap.GetTileX(tile) + exclude_radius);
		y2 = min(AIMap.GetMapSizeY() - 2, AIMap.GetTileY(tile) + exclude_radius);

		list.RemoveRectangle(AIMap.GetTileIndex(x1, y1),AIMap.GetTileIndex(x2, y2));
	}
}

Code: Select all

			Debug("Cargo wants to go to town...");
			local townTiles = AITileList();
			local min = MIN_DISTANCE;
			local max = MAX_DISTANCE;
			local res = SafeAddRectangle(townTiles, place1, max, min, 150000);
			min = res.min;
			max = res.max;
			Debug("Made a list of this many tiles: " + townTiles.Count() + ", min: " + min + ", Max: " + max);

Code: Select all

/**
 * Add a rectangular area to an AITileList containing tiles that are within /radius/
 * tiles from the center tile, taking the edges of the map into account.
 */
function SafeAddRectangle(list, tile, radius, exclude_radius = 0, max_tiles = null) {
	if (tile == null) {
		Error("Got a nullpointer");
		return;
	}

	local rx1;
	local ry1;

	local rx2;
	local ry2;

	local ex1;
	local ey1;

	local ex2;
	local ey2;

	local area_radius;
	local exclude_area_radius = 0;
	local num_tiles;

	do {
		rx1 = max(1, AIMap.GetTileX(tile) - radius);
		ry1 = max(1, AIMap.GetTileY(tile) - radius);

		rx2 = min(AIMap.GetMapSizeX() - 2, AIMap.GetTileX(tile) + radius);
		ry2 = min(AIMap.GetMapSizeY() - 2, AIMap.GetTileY(tile) + radius);

		area_radius = (rx2 - rx1 + 1) * (ry2 - ry1 + 1);

		if (exclude_radius > 0) {
			ex1 = max(1, AIMap.GetTileX(tile) - exclude_radius);
			ey1 = max(1, AIMap.GetTileY(tile) - exclude_radius);

			ex2 = min(AIMap.GetMapSizeX() - 2, AIMap.GetTileX(tile) + exclude_radius);
			ey2 = min(AIMap.GetMapSizeY() - 2, AIMap.GetTileY(tile) + exclude_radius);

			exclude_area_radius = (ex2 - ex1 + 1) * (ey2 - ey1 + 1);
		}

		num_tiles = area_radius - exclude_area_radius;
	}
	while (max_tiles != null && num_tiles > max_tiles && radius-- && exclude_radius++);

	list.AddRectangle(AIMap.GetTileIndex(rx1, ry1), AIMap.GetTileIndex(rx2, ry2));
	if (exclude_radius > 0) list.RemoveRectangle(AIMap.GetTileIndex(ex1, ey1), AIMap.GetTileIndex(ex2, ey2));
	if (max_tiles != null) return {	max = radius, min = exclude_radius };
}